#include "dbutil.sci"
#include "fkutil.sci"
#include "wrap.sci"

// zakładam istnienie pliku my-edok.ini w moim przypadku o zawartości:
// [katalogi]
// KatalogDanych = w:\\edoktest\\
// gdzie KatalogDanych to lokalizacja docelowa plików z pdf'ami

// trochę o strukturze katalogu z dokumentami
// ..KatalogDanych
//  ..nipObsługiwanejFirmy
//   ..rok
//    ..nipKontrahenta lub
//    ..typ dokumentu nie związanego z konkretnym kontrahentem np WB(wyciąg bankowy)

dispatch ws = "WScript.Shell"
dispatch fplik = "Scripting.FileSystemObject"

long    idZlisty, ZrodloDb
long i = 1, NumerKontr = 0
string szukanyPlik , NipFirmy= Firma.Nip , PodKatal, polecenie
string sPath
string katEdok
int errDo

katEdok = GetIni("katalogi","KatalogDanych",Katalog()+"\\my-edok.ini")

string sub FormatEw(string a_ew)
   buf = a_ew
   while replace " ", "_"
   wend
   while replace "/", "_"
   wend
   while replace "\\", "_"
   wend
   FormatEw = buf
endsub

string sub FormatNip(string e_ew)
   buf = e_ew
   while replace "-", ""
   wend
   FormatNip = buf
endsub

int sub przegladajPlik()
   sPath = FileDlg (1, "Dokumenty Acrobat  | *.PDF" )
   przegladajPlik = 1
endsub



            
// określamy bazę dokumentów (bufor czy księgi)
// nie znalazłem zmiennej, funkcji , czy metody która pozwoliłaby określić
// z której bazy korzysta "grid" Lista Dokumentów
// z tąd poniższy sekwencja identyfikująca na podstawie 1 indeksu userObject
// zmienna ZrodloDb określa gdzie jesteśmy 0- księgi, 1- bufor
// nie wiem czy to dobry pomysł aby grzebać w księgach ale....

#define XROWSDATA userObject
   
   idZlisty   = XROWSDATA.item( 1 ).id

BASEHANDLE  bD,bDo

   bD = dbOpenDokBase( indeksRoku(), 1, 0 ) // bufor
      bDo = bD

      SetKey( bDo, "id" )
      SetKeySeg( bDo, "id", XROWSDATA.item( 1 ).id )
      errDo = GetRec( bDo, EQ )

         if  dbNrEwToStr_Dok(bDo)==XROWSDATA.item( 1 ).numer Then
               ZrodloDb = 1
         else
               ZrodloDb = 0
         endif

      // po okrewśleniu żródła danych "skaczemy" do rekordu o ID wskazanego w parametrze Arg0
      // Arg0 zawiera id dokumentu wskazanego prawoklikiem (funkcjonalnosć dostępna jedynie gdy
      // jestesmy "na" Liście Dokumentów, i nie wiadomo czy\kiedy "zniknie")

      if ZrodloDb == 0 then
         DbClose(bD)
            bD = dbOpenDokBase( indeksRoku(), ZrodloDb, 0 )
            bDo = bD
      endif

               SetKey( bDo, "id" )
               SetKeySeg( bDo, "id", val(Arg0) )
               errDo = GetRec( bDo, EQ )

   long    Did      = GetField( bDo, "id")
   string    Dskrot      = GetField( bDo, "skrot")
   long    Dnumer      = GetField( bDo, "numer")
   string    DnumerEw   = dbNrEwToStr_Dok(bDo)
   string    Dnazwa      = GetField( bDo, "nazwa")
   string    Dtresc      = GetField( bDo, "tresc")
   long    DnrKontrah   = GetField( bDo, "kontrahent")
   string    DdataDok   = GetField( bDo, "datadok")
   string    DdataWpr   = GetField( bDo, "datawpr")
   string    DdataOper   = GetField( bDo, "dataoper")
   long    Dkwota      = GetField( bDo, "kwota")
   string    Dnip      = GetField( bDo, "nip")
   int    DeStatus   = GetField( bDo, "eStatus")
   DbClose(bD)

   DnumerEw = formatEw(DnumerEw)
   Dnip    = FormatNip(Dnip)
   NipFirmy = FormatNip(NipFirmy)
   if Dnrkontrah == 0 Then
      PodKatal = Dskrot
   else
      PodKatal = Dnip
   endif
   
   szukanyPlik = katEdok+NipFirmy+ "\\" + NazwaRoku() + "\\"+PodKatal+"\\"+DnumerEw+".PDF"

   if (fplik.FileExists(szukanyPlik)) Then
   // jeśli pdf istnieje wyświetlamy go za pomocą Acrobat Rader i zamykamy raport
      polecenie = "AcroRd32.exe "+szukanyPlik
      ws.Run(polecenie,1,0)   
      close : error ""

   else
      if !(fplik.FolderExists(katEdok)) Then
       fplik.CreateFolder(katEdok)
      endif

      if !(fplik.FolderExists(katEdok+NipFirmy)) Then
       fplik.CreateFolder(katEdok+NipFirmy)
      endif
         if !(fplik.FolderExists(katEdok+NipFirmy+"\\" + NazwaRoku())) Then
             fplik.CreateFolder(katEdok+NipFirmy+"\\" + NazwaRoku())
         endif
            if !(fplik.FolderExists(katEdok+NipFirmy+"\\" + NazwaRoku()+ "\\"+PodKatal)) Then
                fplik.CreateFolder(katEdok+NipFirmy+"\\" + NazwaRoku()+ "\\"+PodKatal)
            endif

   endif
   

   Form "Wskarz dokument PDF", 400, 110
      Medit "", sPath, 10, 10, 300, 40
      button "Szukaj", 320, 10, 60, 22, przegladajPlik()
         Button "&OK", 20, 60, 80, 22, 2
      Button "&Anuluj", 300, 60, 80, 22, -1
    int rv = execform

   if rv == 2 & len(sPath)>0 Then
      fplik.CopyFile(sPath,szukanyPlik)
      If ( Message "Czy skasować plik żródłowy ? DefBtn: &Tak=1 Btn: &Nie=2 Ico:?") == 1 Then
         fplik.DeleteFile(sPath)
      endif

               bD = dbOpenDokBase( indeksRoku(), ZrodloDb, 0 )
               bDo = bD
               SetKey( bDo, "id" )
               SetKeySeg( bDo, "id", val(Arg0) )
               errDo = GetRec( bDo, EQ )
               SetField (bDo, "eStatus", 2)
               PutRec (bDo)
               DbClose(bD)
   endif

close : error ""